pages5.6 差込印刷

失礼致します。　Pages.appの場合はAppleScriptを使うと差し込み印刷が可能です。

1）こちらのサイト（AppleScript関連の情報を提供している）から無料の差し込み印刷用のアプリケーション（Pages Data Merge）をダウンロードできます。　英語ですが、使い方のビデオも閲覧できます。　アプリケーションを開く場合は、システム環境設定＞セキュリティー＆プライバシー＞一般で、ダウンロードしたアプリケーションの実行許可を有効にする必要があります。

→　AppleScript and Pages: Placeholder Text, Script Tags, and Data Merge

2）上のアプリケーションほど複雑な処理を必要としない場合でも、AppleScriptを使うと割と簡単に差し込み印刷が可能です。　上記のアプリケーションで上手くいかない場合は、簡単なものを紹介いたしますので、その旨をご返信ください。

私はpages5.2.2を使用しているのですが、上記アプリケーションではバージョンが古いため、差し込み印刷ができませんでした。

初心者ですが他の方法AppleScriptでの方法を教えて頂けないでしょうか？

初めまして、承知致しました。　私はPages ver.5.2.2を使える環境がないので、まずは、お使いのMacのOSと、アプリケーションフォルダのユーティリティフォルダに、Script Editor.appあるいは、AppleScript Editor.appのどちらがあるか教えて頂けないでしょうか？

まず、AppleScriptでは文字列を引用符（ダブルコーテーション）で囲って指定しますが、スマート引用符の機能で引用符の文字が変わってしまう場合がありますので、システム環境設定＞キーボード＞ユーザ辞書、で（OSに依存して別の場所になっているかもしれないです）『スマート引用符を使用』の項目のチェックを外しておくと良いと思います。

1）Numbersの表の値の取り出し方について、最前面に表示されている書類に以下のような表があるとします。

シートの名前は”シート 1”で（注：半角の数字の前に半角のスペースあり）、表の名前は"表1"、表の列1の名前は”項目1”となっていて、表の一行目はヘッダー行になっています。この表の1列目の全ての値を取り出す方法としては、AppleScript Editor.appあるいは、Script Editor.appに以下のAppleScriptのステートメンツをコピペして実行することになります。 エディタの下の『結果』や『返される値』に列1のセルに入力されている値{"項目1", 1.0, 2.0, 3.0}が表示さることを確認してください。これで、list1に1列目のそれぞれの値がカンマで区切られたリストオブジェクトとして保存されます。

tell front document of application "Numbers"

set list1 to value of cells of column "項目1" of table "表1" of sheet "シート 1"

--> {"項目1", 1.0, 2.0, 3.0}　　注：先頭に--がついた行はコメント行になります。

end tell

同じ列の2行目から最後の行までの値を取り出す場合は、

tell front document of application "Numbers"

set list1 to value of cells 2 thru -1 of column "項目1" of table "表1" of sheet "シート 1"

--> {1.0, 2.0, 3.0}

end tell

とします。　同様に、2列目の値をlist2に入れる場合は、

tell front document of application "Numbers"

set list1 to value of cells 2 thru -1 of column "項目1" of table "表1" of sheet "シート 1"

--> {1.0, 2.0, 3.0}

set list2 to value of cells 2 thru -1 of column "項目2" of table "表1" of sheet "シート 1"

--> {"A", "B", "C"}

end tell

といった具合になります。　同じステートメンツは、少しコンパクトにして、

tell front document of application "Numbers"

tell table "表1" of sheet "シート 1"

set list1 to value of cells 2 thru -1 of column "項目1"

--> {1.0, 2.0, 3.0}

set list2 to value of cells 2 thru -1 of column "項目2"

--> {"A", "B", "C"}

end tell

end tell

としても同じ結果になります。　ご確認ください。

2）次に、Pages.appでの準備としては、（その一例ですが）、差し込み印刷用の雛形の書類を作成して、それをテンプレートとしてして保存します。　詳しくはこちらのリンクを参照してください。　→　AppleScript and Pages: Placeholder Text

3）最後に、以下のAppleScriptを実行するとPages.appの書類のプレースホルダーテキストにNumbers.appの表の情報を差し込んだものが作成されます。

property list1 : {}

property list2 : {}

tell front document of application "Numbers"

set list1 to value of cells 2 thru -1 of column "項目1" of table "表1" of sheet "シート 1"

set list2 to value of cells 2 thru -1 of column "項目2" of table "表1" of sheet "シート 1"

end tell

tell application "Pages"

activate

-- list1の項目数だけ繰り返し処理

repeat with i from 1 to length of list1

--　テンプレート名：”TestTemplate”から新規書類を作成

set thisDocument to makenewdocumentwith properties {document template:template "TestTemplate"}

tell thisDocument

-- "項目1"のタグがついたplacehoder textにlist1のi番目のアイテムを挿入

set (placeholder texts whose tag is "項目1") to item i of list1

-- "項目2"のタグがついたplacehoder textにlist2のi番目のアイテムを挿入

set (placeholder texts whose tag is "項目2") to item i of list2

end tell

--print thisDocument #　プリントする場合

end repeat

end tell

注）Pages ver. 5.6の場合は、AppleScriptに不具合があって、set thisDocument to make …　の後に以下のステートメントを追加してやる必要があります。

tell application "System Events"

tell process "Pages"

key code 0 usingcommand down

end tell

end tell

失礼致します。　

1）私の環境（OS X 10.11.1, Pages ver. 5.6.1）でPages Data Merge.appを試してみましたが（Pages書類として保存）、正常に差し込み操作ができましたよ。　なので、El Capitanだと動かないというわけではないと思います。　セーフブート（Shiftキーを押しながらMacを起動。その後に再起動）などのMacのメンテナンスを実行してみるとどうでしょうか？

2）『簡単な方法』はpatchさんへの返答という形でこのスレッドに書き込んだものですが、如何でしょうか？