AppleScriptでTerminalにKeystrokeが送信できない

> スクリプトエディタにはキー操作の送信は許可されません」となります

AccessibilityにScript Editorを加える必要があります。

また、いつ頃からだったか覚えていませんが、tell processは使えなくなっています。（間違っていたら指摘をお願いします＞識者の方々

System Eventsは、それが呼び出された時、アクティブになっているアプリに作用します。

on run
	tell application "Terminal"
		activate
		do script "sleep 100"
	end tell
	delay 1
	tell application "System Events"
		keystroke "c" using {control down}
	end tell
end run

hohokihai さんによる書き込み：

一応、tell application processは機能しているのかな？でも、いまいち使い所がよく分かりません。ネストの位置も。

こんな感じでどうでしょうか？(Mojave や High Sierra ではこれで大丈夫です)

on run
    tell application "Terminal"
        # 省略
    end tell
    tell application "System Events"
        tell application process "Terminal"
            set frontmost to true -- Terminal を最前面に
            keystroke "c" using {control down}
            delay 1
        end tell
    end tell
end run

あと、do shell script については、Technical Note TN2065 に書いてあるように、tell ブロック外か tell me 内に置いてみるとか。

on run
    tell application "Terminal"
        # 省略
    end tell
    tell application "System Events"
        tell application process "Terminal"
            set frontmost to true -- Terminal を最前面に
            keystroke "c" using {control down}
            delay 1
        end tell
        tell me to do shell script "echo 1" -- A案
    end tell
    do shell script "echo 2" -- B案
end run

ご参考

Technical Note TN2065 > Does it make a difference which application I tell to do shell script?

プログラムの実行時間と実行時のCPU時間を計測する、timeコマンドというものがあり、開発時によく使われます。

AppleScriptの記述を色々と変えながら、時間を計測してみるのも良いかと思います。

"open"コマンドにより、もう一つTerminalを立ち上げてそちらでコマンドを実行し、最初からあるTerminalで計測します。

timeコマンドを使っている際に、killallしてしまうと、計測画面まで閉じられてしまうのでこれは使えません。

open -g -n -a Terminal
time osascript Untitled.scpt

先ずは、Untitled.scptを作って計測を試みましたが、うまく動きませんでした。

Untitled.scpt:

on run
	tell application "Terminal" --後から立ち上げたTerminalが呼ばれる
		activate
		do script "sleep 100" in front window
	end tell
	delay 1
	tell application "System Events"
		tell application process "Terminal" --最初に立ち上げたTerminalが呼ばれる
			set frontmost to true
			keystroke "c" using {control down}
		end tell
	end tell
end run

次に、Untitled2.scptとUntitled3.scptを作って計測してみました。

Untitled2.scpt:

on run
	tell application "Terminal"
		activate
		do script "sleep 100" in front window
	end tell
	delay 1
	tell application "Terminal"
		activate
	end tell
	tell application "System Events"
		keystroke "c" using {control down}
	end tell
	delay 1
	tell application "Terminal"
		quit
	end tell
end run

Untitled3.scpt:

on getProcList(appName)
	set myList to {}
	tell application "System Events"
		set myList to unix id of every process whose name ends with appName
	end tell
	return myList
end getProcList
on run
	set myProc to end of getProcList("Terminal")
	tell application "Terminal"
		activate
		do script "sleep 100" in front window
	end tell
	delay 1
	tell application "System Events"
		set frontmost of every process whose unix id is myProc to true
		keystroke "c" using {control down}
	end tell
	delay 1
	tell application "System Events"
		set frontmost of every process whose unix id is myProc to true
		keystroke "q" using {command down}
	end tell
end run

プロセスのリストを得る方法は、やはり時間が掛かってしまうようです。しかし、どれが正解かに拘らず、色んなパターンを考えるのが上達のコツだと思っていますので、自由にやって下さいませ。

本筋とは外れますが、tell application processについてです。

tell application "Terminal"
	activate
	do script "sleep 100"
end tell
delay 1 --この間にDesktopをクリックしてFinderをactiveにする
tell application "System Events"
	tell application process "Terminal"
		keystroke "c" using {control down} --これは実行されない
	end tell
	delay 1
	tell application process "Terminal"
		do shell script "killall Terminal" --これは実行される
	end tell
end tell

一応、tell application processは機能しているのかな？でも、いまいち使い所がよく分かりません。ネストの位置も。

tell application "Terminal"
	activate
	do script "sleep 100"
end tell
delay 1 --この間にDesktopをクリックしてFinderをactiveにする
tell application "System Events"
	keystroke "c" using {control down} --これは実行されない
end tell
delay 1
tell application "Terminal"
	do shell script "killall Terminal" --これは実行される
end tell

これでも動作は同じ。スクリプトなので行数は少ない方がいいし。どう思われますか？

> 「スクリプト.app」をaccessbilityに登録して実行しても、

> エラーは出ませんがKeyStrokeを拾ってくれません。

こちらでは、KeyStroke実行してくれますけど...

ちなみに、accessbilityのチェックを外すとエラーが出ます。

"set frontmost to true"を入れると、Terminalプロセスの呼び出しが意味を持ちますね！

"do shell script"は、"so for optimal results always put do shell script calls outside of any tell block"とのことで、B案に賛成です。

> でも「tell process」でないと「unix id」が取れないんです。

unix idがtell processでないと取れないのなら、tell processを使う意味はあると思います。

killallを使うなら、tellブロック外にするのが良いようですね。