.page や .key ファイルを一括して .docx や .pptx に変換するには？
Pages や Keynote で作成した多くの文書やプレゼンファイルがあるのですが、それらを一気に Microsoft Office ファイルに変換する方法・手順をお教え下さい。
Automator のライブラリには該当するような項目が無いようですが、Apple scriptなどを使えばできるのでしょうか？
よろしくお願い致します。
iMac (2017 – 2020)
スレッドに付いたマーク
ベストな回答
すみません。こちらでも事象を確認できました。
ファイルを正常に開けてなかった？ようです。
convert(dirName, fileName, appName, exportFormat, exportExtension)ハンドラ内の
「set doc to open fullPath」 を 「set doc to open (fullPath as alias)」に書き換えました。
これでどうでしょうか。
----------
tell application "Finder"
set aSel to the selection as alias list
end tell
if aSel = {} then return
repeat with theFile in aSel
tell application "Finder"
set fExt to (name extension of theFile) as string
set fName to (name of theFile) as string
set fDir to (folder of theFile) as string
end tell
if fExt is "pages" then
tell application "Finder"
if not (exists folder "docx" of (fDir as alias)) then make new folder at (fDir as alias) with properties {name:"docx"}
end tell
using terms from application "Pages"
convert(fDir, fName, "Pages", Microsoft Word, "docx") of me
end using terms from
end if
end repeat
on convert(dirName, fileName, appName, exportFormat, exportExtension)
tell application appName
set fullPath to (dirName & fileName)
set doc to open (fullPath as alias)
set docName to name of doc
set aRes to confirmationOfFileExisting(dirName & "docx:", docName, exportExtension) of me
set exportFileName to aRes as string
if appName is "Pages" then
tell application "Pages"
export doc to file exportFileName as exportFormat
end tell
end if
close doc
end tell
end convert
on confirmationOfFileExisting(dirName, docName, exportExtension)
tell application "Finder"
set exportFileName to (dirName & docName & "." & exportExtension) as string
if (exists file (exportFileName)) then
repeat with i from 2 to 65536
if not (exists file (dirName & docName & " " & i & "." & exportExtension)) then
set exportFileName to (dirName & docName & " " & i & "." & exportExtension)
exit repeat
end if
end repeat
end if
end tell
return exportFileName
end confirmationOfFileExisting
----------
