AppleScriptでリマインダーにタスクを自動で追加したい

う〜ん、これでいけますかね？

バッテリー残量取得についてはうまく取得できているか、バッテリー搭載機を使ってないのでわかりません。

タスクが見つからない場合かつバッテリー残量が80%未満の場合には、10秒後にリマインドを設定。

既存のタスクがある場合かつバッテリー残量が80%未満の場合には、実行済みを解除し、10秒後にリマインドを設定。みたいな..

-- バッテリー残量を取得
set batteryLevel to (do shell script "pmset -g batt | grep -o '\\d\\+%' | tr -d '%'") as integer

-- 現在の日時
set curDate to (current date)

-- オートメーションというリストを取得
tell application "Reminders"
	set automationList to list "オートメーション"
	set taskFound to false
	
	-- タスクを検索
	repeat with i from 1 to (count of reminders in automationList)
		set taskName to name of reminder i of automationList
		if taskName is equal to "MacBookの電池残量低下" then
			set taskFound to true
			exit repeat
		end if
	end repeat
	
	if not taskFound and batteryLevel < 80 then
		-- タスクが見つからない場合かつバッテリー残量が80%未満の場合
		set newTask to make new reminder at end of reminders of automationList with properties {name:"MacBookの電池残量低下", remind me date:curDate + 10} -- タスクを新規作成し10秒後にリマインドを設定
	else if taskFound and batteryLevel < 80 then -- 既存のタスクがある場合かつバッテリー残量が80%未満の場合
		set completed of reminder "MacBookの電池残量低下" to false -- 実行済みを解除
		set remind me date of reminder "MacBookの電池残量低下" to (curDate + 10) -- 10秒後にリマインドを設定
	end if
	quit -- アプリを終了。必要かどうか？
end tell