AppleScriptのtell文についての質問です

確認作業ありがとうございます。

まず、Firefox について。vz.r さんの変更版は当方でも動きました。もし Sonoma でも動くようなら下図のように AppleScript の前に「入力からテキストを取得」を置くのもありかと。

ーーーーー

次に、最後の入力のところは、こんな感じでどうでしょうか。Ventura はこれでいけます。

変更前

                tell sheet 1 of sheet 1
                    set value of text field 2 of group 1 of scroll area 1 of group 1 to aPhrase
                end tell

変更後

                tell sheet 1 of sheet 1
                    tell group 1's scroll area 1's group 1
                        set focused of text field 2 to true
                        set value of text field 2 to aPhrase
                    end tell
                end tell

# 文章を若干変更しました。

ありがとうございます。

「入力からテキストを取得」「入力のところのAppleScript」 Sonomaでも動作しました。

その方法の方がスマートですね。

tell sheet 1 of sheet 1
	--set value of text field 2 of group 1 of scroll area 1 of group 1 to aPhrase
	tell group 1's scroll area 1's group 1
		set focused of text field 2 to true
		set value of text field 2 to aPhrase
		delay 0.4 --フォーカス移動の動作を遅延させるため記述。
		set focused of text field 1 to true
	end tell
end tell

Hiro__Sさんご提示のスクリプトに、フォーカスをtext field 1に戻す一文を追加しました。

ご提示のもので完成度が上がりましたね！ありがとうございました。

横から失礼します。

このワークフローは当方の環境ではうまく動かないので二点確認をお願いします。

まず一点目。Firefox 上でテキストを選択した際に期待どおりの結果が得られるかを確認して欲しいです。当方ではテキストエディットなどは問題ありませんが Firefox で上手くいきません。

二点目。最後に表示されるシートで「入力/読み」を入力すると「追加」ボタンが有効になるかを確認して欲しいです。当方では「入力/読み」を入力しても「追加ボタン」が有効になりません。

Sonoma で問題ないならこのままでも良いと思いますが、Ventura でも、、、ということなら若干変更しなければならないかなと。問題の回避策は既に見つけたので必要なら後ほどポストします。

当方の環境

• Ventura 13.6.6 (Parallels Desktop 18)
• Firefox 125.0.3

最前面のアプリなら指定や取得ができますが、スクリプトエディタ上で実行すると自身を取得してしまうので、スクリプトの実行方法が限られます。

Automatorやショートカットアプリで選択したテキストを右クリックのメニューからスクリプトに送る“サービス”を作成するのがいいかもしれません。

現状、どのような実行方法をお考えでしょう？

サービスについて回答を作成しますので、少しお待ちください。

それから、先ほどのスクリプトを構文確認をパスし動作させられる状態にするには、下記のように記述します。

スクリプトエディタ上にコピペし、語句を選択状態で実行すると、選択したところがコピーされます。

追記

キーイベントを動作させるには、「System Events」を呼び出す必要があります。

また、その機能を使うには、システム設定のアクセシビリティで許可が必要です。

もう許可されているなら大丈夫です。

-- 最前面のアプリケーション名を取得（appName）
use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

set frontApp to POSIX path of (path to frontmost application)
set appName to ((current application's NSString's stringWithString:frontApp)'s lastPathComponent()'s stringByDeletingPathExtension) as string
--display dialog appName

-- コマンドキーを押しながらc（コピー）
tell application "System Events"
	tell process appName
		key code 8 using command down
		--keystroke "c" using {command down}
		delay 1
	end tell
end tell

お待たせしております。

“ショートカット”アプリでの作成になりますが、下記のようにアクションを組んで実行させれば..

スクリプト：

on run {input, parameters}
	tell application "System Settings"
		checkSheet() of me
		reveal anchor "TextReplacements" of pane id "com.apple.Keyboard-Settings.extension"
		activate
		inputText((input's item 1) as string) of me
	end tell
	
	return input
end run

on checkSheet()
	activate application "System Settings"
	tell application "System Events"
		tell process "システム設定"
			repeat
				if exists (every sheet of window 1) then
					set frontmost to true
					key code 53
					delay 0.3
				else
					exit repeat
				end if
			end repeat
		end tell
	end tell
	delay 0.3
end checkSheet

on inputText(aPhrase)
	activate application "System Settings"
	tell application "System Events"
		tell process "システム設定"
			-- insert GUI Scripting statements here:
			repeat until (exists sheet 1 of window 1)
				--delay 0.4
			end repeat
			tell window 1
				tell sheet 1
					click button 1 of group 1 of scroll area 1 of group 1
				end tell
				repeat until (exists sheet 1 of sheet 1)
					--delay 0.4
				end repeat
				delay 0.3
				tell sheet 1 of sheet 1
					set value of text field 2 of group 1 of scroll area 1 of group 1 to aPhrase
				end tell
			end tell
		end tell
	end tell
end inputText

スクリプト文は一例です。

ご自身で組んだものを内包しても大丈夫ですよ。

https://youtu.be/Lv6xc-wdd40

完璧な回答は難しいので、わからないところあればその都度おっしゃってください。

わかる範囲内ならお答えできます。

追伸 動作させるアプリをアクセシビリティで許可する必要があると思います。

一点目：

Firefox 125.0.3 で確認してみました。

私の環境でもそのままではうまく行かず、対策としてショートカットのアクションを追加してみました。

これでどうでしょう？

use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

on run
	set frontApp to POSIX path of (path to frontmost application)
	set appName to ((current application's NSString's stringWithString:frontApp)'s lastPathComponent()'s stringByDeletingPathExtension) as string
	
	if appName = "Firefox" then
		return true
	else
		return {}
	end if
end run

二点目：

＞最後に表示されるシートで「入力/読み」を入力すると「追加」ボタンが有効になるかを確認して欲しいです。当方では「入力/読み」を入力しても「追加ボタン」が有効になりません。

すみません。そこまでは確認してなかったです。

そのままでは有効にならず、変換/語句に何かテキストを入力操作して入力したいらないものを削除 としないといけないようです？

＞問題の回避策は既に見つけた

是非教えてください。

こちらこそ勉強になりました。ありがとうございます。

最前面のアプリケーション名を取得できたらいいっていうのなら、こんな感じで取得整形できます。

use AppleScript version "2.4"
use scripting additions
use framework "Foundation"

set frontApp to POSIX path of (path to frontmost application)
set appName to ((current application's NSString's stringWithString:frontApp)'s lastPathComponent()'s stringByDeletingPathExtension) as string

display dialog appName