Macのミュージックで作ったプレイリストの画像を従来の4分割ジャケット表示にする方法

おぉ、素晴らしい！

こんな簡単な方法があったんですね。

私は以下のようなAppleScriptを作ってそれでプレイリストを作成することで過去の四分割アートワークを表示させていましたが...

set myArtists to ""
set myAlbum to ""
set myDefPlaylist to ""

tell application "Music"
	activate
	
	-- 選択中の曲を追加するか？
	set mySelection to selection as list
	if (count mySelection) > 0 then
		display dialog "選択中の曲を追加しますか？" with title "プレイリスト作成" buttons {"Yes", "No"} default button 1
		set myAddSongs to result's button returned
		if (myAddSongs = "Yes") then
			repeat with mySong in mySelection
				set myArtists to mySong's artist
				set myAlbum to mySong's album
				set myDefPlaylist to myArtists & " - " & myAlbum
			end repeat
		end if
	end if
	
	-- プレイリスト名の取得
	display dialog "プレイリスト名を入力" default answer myDefPlaylist with title "プレイリスト作成" buttons {"Cancel", "OK"} default button 2 cancel button 1
	set myPlaylist to result's text returned
	if (count myPlaylist) = 0 then return
	
	-- プレイリストを作成
	make new playlist with properties {name:myPlaylist}
	
	-- 選択中の曲をプレイリストに追加
	if (count mySelection) > 0 and (myAddSongs = "Yes") then
		repeat with mySong in mySelection
			duplicate mySong to playlist (myPlaylist)
		end repeat
	end if
	
	set view of front window to playlist (myPlaylist)
	
end tell