既存MP3ファイルをAACファイルに置き換えたい

AppleScript を拵えて見ました。不要かもしれませんが、貼っときます。

処理済みの MP3 ファイルをゴミ箱に捨てたい場合は、コードを次のように変更してください。

変更前

my main(0)

変更後

my main(1)

ーーーーー

簡単な説明:

MP3 のトラック情報を、AAC トラックにコピーし、不要となったトラックはプレイリストから削除する AppleScript

コピー項目:

• 最終再生日 (AAC トラックの変更日をコピー)
• 再生回数
• レート
• 歌詞
• アートワーク (最初の一枚のみ)

スクリプトの作り方:

1. 下記「コード」をスクリプトエディタにコピーし
2. スクリプト形式で保存

使い方:

1. iTunes で「ライブラリ > 曲」を表示
2. 処理対象のアルバムを選択
3. 「トラック番号」でソート
4. アルバム内の全曲を選択 (図1)
5. スクリプトエディタから、スクリプトを実行

図1 処理前

図2 処理後

注意点:

• MP3 トラックと、AAC トラックの曲数が同じである必要がある
• MP3 トラックと、AAC トラックの曲名、アルバム名が同じである必要がある

動作確認:

macOS High Sierra 10.13.6 / iTunes 12.8.0

ーーーーー

コード

on run
    try
        if application "iTunes" is not running then
            return
        end if

        #
        # パラメータ
        #   0 : MP3 ファイルをそのままにする
        #   1 : MP3 ファイルをゴミ箱に捨てる
        #
        my main(0)
    on error errs number errn
        return errs
    end try
end run

on main(flag)
    do shell script "osascript <<'OSA' - " & quoted form of (flag as text) & "
on run(argv)
    tell application \"iTunes\"
        set flag to item 1 of argv as integer

        set old_tracks to {} # MP3
        set new_tracks to {} # AAC
        set old_tracks_location to {}

        repeat with i in selection as list
            if kind of i starts with \"MPEG\" then
                set end of old_tracks to contents of i
                set end of old_tracks_location to location of i
            else
                set end of new_tracks to contents of i
            end if
        end repeat

        # copy tags
        my copy_tags(old_tracks, new_tracks)

        # delete tracks
        my delete_tracks(new_tracks, old_tracks_location, flag)

        --return
    end tell
end run

on copy_tags(old_tracks, new_tracks)
    tell application \"iTunes\"
        count artworks of item 1 of old_tracks
        if result > 0 then
            set img to data of artwork 1 of item 1 of old_tracks
        else
            set img to false
        end if

        repeat with i from 1 to length of old_tracks
            set t1 to name of item i of old_tracks
            set t2 to name of item i of new_tracks

            set a1 to album of item i of old_tracks
            set a2 to album of item i of new_tracks

            if t1 is t2 and a1 is a2 then
                # 最終再生日
                set played date of item i of new_tracks ¬
                    to modification date of item i of new_tracks as date

                # 再生回数
                set played count of item i of new_tracks ¬
                    to played count of item i of old_tracks as integer

                # レート
                set rating of item i of new_tracks ¬
                    to rating of item i of old_tracks as integer

                # 歌詞
                set lyrics of item i of new_tracks ¬
                    to lyrics of item i of old_tracks as text

                # アートワーク
                if img is not false then
                    set data of artwork 1 of item i of new_tracks to img
                end if

                #
                # ファイルパス
                #   旧トラック (MP3) のファイルパスを、新ファイル (AAC) のパスに変更
                #
                set location of item i of old_tracks ¬
                    to location of item i of new_tracks as alias
            end if
        end repeat
    end tell
end copy_tags

on delete_tracks(new_tracks, old_tracks_location, flag)
    tell application \"iTunes\"
        repeat with f in new_tracks
            delete f
        end repeat

        if flag is 1 then
            tell application \"Finder\"
                delete old_tracks_location
            end tell
        end if
    end tell
end delete_tracks
OSA"
end main

izacks による書き込み:

プレイリストの情報や再生回数、レートなどはそのまま継続させたい。

これは、お書きの方法でも下記の方法でも、無理じゃないかと思うけど。

iTunesにAACへの変換のメニューがありませんか。

izacks による書き込み:

その上でファイル情報等は活かしたいのです。

試してみればいいだけの話ですが、同じ曲（の上書き）との認識もされないでしょうから、無理なんでは。

重要な事を書き忘れたので、追記します。

再取り込みする際に曲情報を持ったMP3が無いと曲情報の引継ぎができませんので削除は最後にと言う事になります。

一部勘違いがありましたので訂正しておきます。

古いMP3はゴミ箱にも入らずに自動的に削除されます

古いMP3はライブラリから削除された後、ゴミ箱に移動されます