AppleScriptObjC でエイリアスのオリジナルを得たい

こんな感じでどうでしょうか？

ASOC

use AppleScript version "2.5"
use scripting additions
use framework "Foundation"

property OSX : current application
property nil : missing value

on run
    set dstfpath to OSX's NSString's stringWithString:(POSIX path of (choose file))
    set dstfurl to OSX's NSURL's fileURLWithPath:dstfpath

    set {res, is_alias} to dstfurl's ¬
        getResourceValue:(reference) forKey:(OSX's NSURLIsAliasFileKey) |error|:nil

    if res then
        if is_alias then
            set o1 to OSX's NSURLBookmarkResolutionWithoutUI
            set o2 to OSX's NSURLBookmarkResolutionWithoutMounting
            set opt to o1 + o2
            set srcfurl to OSX's NSURL's ¬
                URLByResolvingAliasFileAtURL:dstfurl options:opt |error|:nil
            set srcfpath to srcfurl's |path| as text
            return srcfpath
        else
            return "not alias file: " & dstfpath as text
        end if
    end if
end run

JXA

'use strict';

var App = Application.currentApplication(); App.includeStandardAdditions = true;

function run() {
    let dstfpath = App.chooseFile().toString();
    let dstfurl = $.NSURL.fileURLWithPath(dstfpath);
    let is_alias = $();
    if (dstfurl.getResourceValueForKeyError(is_alias, $.NSURLIsAliasFileKey, $())) {
        if (is_alias.js) {
            let srcfurl = $.NSURL.URLByResolvingAliasFileAtURLOptionsError(
                dstfurl,
                $.NSURLBookmarkResolutionWithoutUI | $.NSURLBookmarkResolutionWithoutMounting,
                $()
            );
            let srcfpath = srcfurl.path.js;
            return srcfpath;
        } else {
            return `not alias file: ${dstfurl.path.js}`;
        }
    }
}

訂正

誤: choose file ではシンボリックリンク自体を選択することができません。

正: choose file ではシンボリックリンク自体のパスを取得することができません。

ーーーーー

choose file とした際のシンボリックリンクの問題は解決できませんが、次のようにすればエイリアスファイルのみを選択することはできます。

choose file of type {"com.apple.alias-file"}

となると、対象のファイルがエイリアスであるか否かの判別が不要となるのでコードはかなり短くできますね。

use AppleScript version "2.5"
use scripting additions
use framework "Foundation"

property OSX : current application
property nil : missing value

on run
    set dstfpath to choose file of type {"com.apple.alias-file"}
    set dstfurl to OSX's NSURL's fileURLWithPath:(dstfpath's POSIX path)

    set {srcfurl, err} to OSX's NSURL's ¬
        URLByResolvingAliasFileAtURL:dstfurl options:0 |error|:(reference)

    if err is nil then
        set srcfpath to srcfurl's |path| as text
        return srcfpath
    else
        return err's localizedDescription as text
    end if
end run

ーーーーー

あと、エイリアスのオリジナルを得るにはこんな方法もあります。

URLByResolvingBookmarkData:options:relativeToURL:bookmarkDataIsStale:error:

https://developer.apple.com/documentation/foundation/nsurl/1572035-urlbyresolvingbookmarkdata

具体的なコードは省略しますが、URLByResolvingAliasFileAtURL:options:error: より詳細な情報を取得できます。bookmarkDataIsStale がミソ。

まあ、Finder からオリジナルを求める方法の代わりとしては、URLByResolvingAliasFileAtURL:options:error: で十分でしょうけど、一応、ご参考まで。

戻り値はリスト型になります。それが AppleScriptObjC の特徴でしょうね。さらに次のようにするとエラー内容も捕獲できます。(リストの要素数が一つ増えます)

use AppleScript version "2.5"
use scripting additions
use framework "Foundation"

property OSX : current application
property nil : missing value

on run
    set dstfpath to OSX's NSString's stringWithString:(POSIX path of (choose file))
    set dstfurl to OSX's NSURL's fileURLWithPath:dstfpath

    set {res, is_alias, err} to dstfurl's ¬
        getResourceValue:(reference) forKey:(OSX's NSURLIsAliasFileKey) |error|:(reference)

    log res
    log is_alias as boolean
    log err
end run

ちなみに冒頭のコードも次のようにすればエラーを捕獲できます。(reference) がミソ。

use AppleScript version "2.5"
use framework "Foundation"
use scripting additions

set aFile to choose file

set {r, err} to current application's NSFileManager's defaultManager()'s ¬
    destinationOfSymbolicLinkAtPath:(POSIX path of aFile) |error|:(reference)

log r
log err

if err is missing value then
    r
else
    err's localizedDescription as text
end if

エイリアスのオリジナルを得るコードはこんな感じでも良いかもしれません。オリジナルが不明のエイリアス、シンボリックリンク、ディレクトリ、通常ファイルを Finder で選択してスクリプトを実行してみてください。

use AppleScript version "2.5"
use scripting additions
use framework "Foundation"

property OSX : current application
property nil : missing value

on run
    tell application "Finder"
        set dstfobj to item 1 of (selection as list)
        set dstfurl to OSX's NSURL's URLWithString:(URL of dstfobj)
    end tell
    set attrs to dstfurl's resourceValuesForKeys:{"NSURLIsAliasFileKey"} |error|:nil
    if (attrs's objectForKey:"NSURLIsAliasFileKey") as boolean then
        set {srcfurl, err} to OSX's NSURL's URLByResolvingAliasFileAtURL:dstfurl options:0 |error|:(reference)
        if err is nil then
            set srcfpath to srcfurl's |path| as text
            return srcfpath
        else
            #
            # could not resolve alias
            #
            return err's localizedDescription as text
        end if
    else
        return "not alias or symbolic link: " & dstfurl's |path| as text
    end if
end run

ところで、choose file の戻り値には注意が必要です。エイリアスの場合は問題ありませんが、シンボリックリンクを選択するとオリジナルのパスが返されます。つまり choose file ではシンボリックリンク自体を選択することができません。

一方 Finder でファイルを選択した場合はシンボリックリンクでも大丈夫。ただし、... as alias とするとオリジナルになるので要注意。(結構面倒です...)