バナー「互換性のないディスク」を表示しない、またはそもそも出ないようにしたい．あるいは……

light289 さんによる書き込み：

何とか「手間なく=自動で」消す、もしくはそもそも表示させない方法はないでしょうか．

雑な方法ですが Automator の「記録」でなんとかなります。私の環境では。

MacのAutomatorでワークフローを作成する - Apple サポート (日本)

ちなみに内蔵ディスクは Big Sur、外付け SSD は Catalina、Mojave ですが Catalina では「互換性のないディスク」は表示されないのでそういうものなんだろうと。

連投申し訳ありません。自明だと思いますが念のため手順を記すと（再）ログインして「互換性のないディスク」を表示して「閉じる」の任意の場所にポインタを移動して Automator を開いて（必要に応じて command + N とかシステム環境設定のセキュリティとプライバシーとかをごにょごにょして）option + command + R として「閉じる」をクリックして中止ボタンをクリックします。

MacのAutomatorでワークフローを作成する - Apple サポート (日本)

というか質問に「Objective-C の NSWorkspaceWillPowerOffNotification」とか書いてる人に一定の水準を期待するのは法外ではないと思うのですが（なので上級者にとってはエレガントではないだろうなあと思ったのです）。一から十まで説明とか流石に勘弁してくださいというか。

念の為ですが Automator で「閉じる」ボタンをクリックする操作を「記録」して（「再生速度」などを調整して）アプリケーションとして保存してログイン項目に追加します（「システム環境設定」＞「セキュリティとプライバシー」＞「プライバシー」＞「アクセシビリティ」でそのアプリケーションを「許可」する必要があります）。もっとエレガントな方法があると思いますが（AppleScript とか？）要は何らかの方法で「閉じる」ボタンを自動的にクリックすれば良いと思います。

light289 さんによる書き込み：

OS をCatalina にするという選択肢は絶対にありません．

そういうことではなく Monterey や Big Sur が含まれるマルチブート環境に於いて「互換性のないディスク」通知パネルは Catalina 以降は（今のところ）表示されないだろうということです。つまり

Monterey: 表示されない

Big Sur: 表示されない

Catalina: 表示されない

Mojave: 表示される

High Sierra: 表示される（日本語環境でも Incompatible Disk）

Sierra: 表示される？（APFS は非公式だがマウントできる）

El Capitan: 表示されない（APFS をマウントできないので）

ということです。

次に GUI スクリプティングについて。

下の要領で都度 UI Elements を取得して、その結果から目的の要素を探していきます。Xcode に付属の Accessibility Inspector.app を併用すると若干作業効率が良くなるかもしれません。また、Automator の記録から得られた AppleScript のコードが役に立つ場合もあります。(何れにしてもかなり根気のいる作業です)

tell application "System Events"
    tell application process "NotificationCenter"
        UI Elements # 結果から目的の要素を探す (この場合は window 1)
        tell window 1
            UI Elements # 結果から目的の要素を探す (この場合は button "閉じる")
            click button "閉じる"
        end tell
    end tell
end tell

「通知」の「閉じる」ボタンを押すための最小限のコードはこんな感じでしょうか。(ボタンが2つあるタイプの通知で試したので若干違うかもしれません。ダメな場合は適宜書き換えてください)

tell application "System Events"
    tell application process "NotificationCenter"
        -- set frontmost to true
        tell window 1
            click button "閉じる"
        end tell
    end tell
end tell

いくつかの機能 (通知ウインドウが出現するまで待つなど) を追加するとこんな感じ。

on run
    try
        main()
    on error errs number errn
        tell me
            activate
            display alert "Error!" message errs as critical
        end tell
    end try
end run

on main()
    set notification_title to "互換性のないディスク"
    set close_button to "閉じる"
    --
    tell application "System Events"
        tell application process "NotificationCenter"
            set n to 0
            repeat while true
                if n > 30 then error "timed out"
                set _windows_ to windows whose static text 1's value is notification_title
                if _windows_'s length > 0 then
                    set _window_ to _windows_'s item 1
                    exit repeat
                else
                    delay 1
                    set n to n + 1
                end if
            end repeat

            -- set frontmost to true

            tell _window_
                click button close_button
            end tell
        end tell
    end tell
end main

で、Automator か AppleScript でアプレットを作成し、ログイン項目に登録すると良いと思います。

# システム環境設定の「セキュリティとプライバシー > アクセシビリティ」へ登録後にアプレットを編集すると、不許可となってしまうようです。なので、アプレットを編集した際は登録し直す必要があるみたいです。(めんどくさい...)

> これらのデータを AppleScript 側へ渡す方法

run script を使ってみるとか。ただ、これもバグがあって、with parameters オプションを付けるとクラッシュします...。同オプションが不要ならこんな感じでしょうか。

on run
    set js to "// JavaScript
'use strict';

ObjC.import('Cocoa');

function run() {
    const res1 = $.CGWindowListCopyWindowInfo(
        $.kCGWindowListOptionOnScreenOnly,
        $.kCGNullWindowID
    );
    const res2 = ObjC.deepUnwrap(res1);
    return res2;
}"

    run script js in "JavaScript"
end run

まず、Automator の「記録」について。

Automator で「記録」した結果は下図のようにすると AppleScript のコードを得ることができます。で、その中から必要な部分を抜き出してコードを整えると、簡単に AppleScript を作成できます。

下記のページが参考になるかな？

失敗例と成功例の動画も貼られているので、わかりやすいかと。

https://blog.goo.ne.jp/ita-shin/e/ef154af8042b38a9db14f991169b9e65

> 低速なディスク(SATA-SSD)を起動・稼働に用いる

thunderbolt 接続のnvme m.2 ssd を使うなら、40Gbpsまで出せますので、内蔵ssdと遜色ないですよ。