【AppleScript】Finder上の選択ファイルを複製後、複製したものを選択状態にするには

リネーム後のパス名のリストを作成し、それを select すれば良いと思います。

例えばこんな感じ。

tell application "Finder"
    activate

    set theString to "-a" --追加する文字

    set Allsel to selection as alias list --選択ファイル
    set ff to {} -- リネーム後のファイルのパスのリスト

    repeat with sel in Allsel
        set FileName to name of sel as text --選択ファイル名
        set FileNameChrList to every character of FileName --選択ファイル名の文字列
        set tmpFileName to reverse of FileNameChrList as text --ファイル名の文字列を逆にしたもの
        set c to offset of "." in tmpFileName --ドットの位置
        set preFix to reverse of (characters 1 thru c of tmpFileName) --ドットから拡張子までの文字列
        set retFileName to reverse of (characters (c + 1) thru (length of tmpFileName) of tmpFileName) --拡張子前の文字列

        set DirName to sel's container as text
        set NewFileName to (retFileName as text) & (theString as text) & (preFix as text)

        set duplicatedFile to duplicate sel --選択ファイルを複製
        set name of duplicatedFile to NewFileName -- 複製したファイル名を変更

        set end of ff to (DirName & NewFileName) as alias
    end repeat

    select ff
end tell

# as string、as Unicode text、selection は次のように勝手に変更しました。

as string => as text

as Unicode text => as text

selection => selection as alias list

動作確認: macOS 10.14.6

s55k1n8 さん、こんにちは。

すでにご確認済みかもしれませんが、関連する情報として以下の記事をご参照ください。

• Mac で AppleScript および「ターミナル」を使ってタスクを自動化する - Apple サポート (日本)
• Mac 用スクリプトエディタユーザガイド - Apple サポート (日本)

今後とも Apple サポートコミュニティをよろしくお願いします。

※この投稿では、引き続きユーザの皆様からの情報を募集しています。