フォルダ内の階層全てのエイリアスを作りたい

私もなんとかできました。

ちょっとコードが複雑でもっと整理できるかもしれませんが、動作確認はできています。

なお、お伺いした目的からAliasフォルダはデスクトップ固定で作成することにしましたので、作成後に所定の場所に移動してください。

参考になれば幸いです。

on run
	
	--ターゲットフォルダの選択
	set tgtfolder to choose folder
	set tgtpath to tgtfolder's POSIX path
	
	--エイリアスフォルダの場所：デスクトップに固定
	set aliasfolder to ((path to desktop folder) as text) & "Alias:"
	set aliaspath to aliasfolder's POSIX path
	
	--フォルダ階層を複製：ここがキモ！
	do shell script "rsync -ar --include \"*/\" --exclude \"*\" " & tgtpath's quoted form & " " & aliaspath's quoted form
	
	tell application "Finder"
		set getfiles to ((folder tgtfolder)'s entire contents)'s files
		repeat with getfile in getfiles
			set parentpath to ((parent of getfile) as alias)'s POSIX path
			set putaliaspath to my replaceText(parentpath, tgtpath, aliaspath) --エイリアスの作成場所
			make new alias at POSIX file putaliaspath to getfile --エイリアスの作成
		end repeat
	end tell
	
end run


on replaceText(theText, serchStr, replaceStr)
	set tmp to AppleScript's text item delimiters
	set AppleScript's text item delimiters to serchStr
	set theList to every text item of theText
	set AppleScript's text item delimiters to replaceStr
	set theText to theList as string
	set AppleScript's text item delimiters to tmp
	return theText
end replaceText