AppleScript でシステム環境設定からリーモートマネジメントをオフし、その後オンする操作を実行できますか

システム設定ではなく、システム環境設定ってことは古いOSになってしまいますけど、動作させたいのはSonoma上でしょうか？

他の質問で解決されたと見かけたのですが、こんな感じでもどうでしょう？

接続先上で実行する必要があると思いますが、こんなAppleScriptで。

if application "System Settings" is running then
	tell application "System Events"
		tell process "システム設定"
			tell application "System Settings" to activate
			if (exists sheet 1 of window 1) then
				key code 53
				delay 0.8
			end if
		end tell
	end tell
end if

tell application "System Settings"
	reveal anchor "Services_ARDService" of pane id "com.apple.Sharing-Settings.extension"
	activate
	repeat until (exists window "共有")
		delay 0.4
	end repeat
end tell

activate application "System Settings"
tell application "System Events"
	tell process "システム設定"
		tell window "共有"
			repeat until (exists sheet 1)
				delay 0.4
			end repeat
			tell group 1 of scroll area 1 of group 1 of sheet 1
				if ((get value of checkbox 1) as boolean) then
					click checkbox 1
					delay 2
					click checkbox 1
					delay 0.4
					beep
					delay 1
				else
					--click checkbox 1
				end if
			end tell
		end tell
	end tell
end tell

私のも一例です。

ちゃんと動作すればどんなコードでもいいですよね。私も、UI Browser頼りのところがあります。

GUIスクリプティングにするとき、態々調べて階層を辿っていかなくていいんで便利ですよね。

あと、下記のようなスクリプトを実行すると指定したpaneの選択したanchorを使ったスクリプトが得られます。

何かの役にでも立てば..

（システム設定の起動完了を待たずして先にコードが進行してしまうので、システム設定が立ち上がった状態で実行してください。また違うスクリプトですが、手動で開いた現在のpaneのすべてのanchorを取得して、リストから選択してスクリプトを作成することもできます。いろいろ試してみてください。）

tell application "System Settings"
	activate
	set pList to id of every pane
	set paneId to choose from list pList with title "paneのIDを選択"
	if paneId is false then return
	set anchor_ to (choose from list (get name of every anchor of pane id paneId) with title "anchorを選択")
	if anchor_ is false then return
	
	--reveal anchor (anchor_ as text) of pane id paneId
	
	set winName to get name of pane id paneId
	
end tell

set aCmd to "tell application \"System Settings\"
reveal anchor " & "\"" & (anchor_ as text) & "\"" & " of pane id " & "\"" & paneId & "\"
activate
repeat until (exists window \"" & winName & "\")
--delay 0.4
end repeat
end tell
"

--set the clipboard to aCmd


tell application "Script Editor"
	activate
	check syntax of (make new document with properties {text:aCmd})
end tell

ライセンス通りましたか。それは良かったです。

現状のUI Browser 3.0.2はこちらから。

ライセンスがない場合は、トライアルモードで30日間実行されるようですね。その後制限モードになる？

後継のバージョン4はオープンソースプロジェクトで進行されているよう？です。

Late Night SoftwareのUI BROWSER 4のページ。

バージョン4楽しみですね。