AutomatorでGoogleスプレッドシートの特定セルにクリップボードの値を貼り付けるには？

開いているChromeのタブのURLを検索して見つけたらアクティブにする

こんな感じの AppleScript で大丈夫だと思います。「xxx」のところには URL を書いてください。

on run
    set target_url to "xxx" # <= ここに URL を書く

    tell application "Google Chrome"
        activate
        repeat with w in windows
            if w's tabs's URL contains target_url then
                set w's index to 1
                set exists_target_url to true
                exit repeat
            else
                set exists_target_url to false
            end if
        end repeat

        tell window 1
            if exists_target_url then
                repeat with i from 1 to count tabs
                    if URL of tab i is target_url then
                        exit repeat
                    end if
                end repeat
                set active tab index to i
            else
                open location target_url
            end if

            set n to 0
            repeat while active tab is loading
                delay 1
                if n < 5 then
                    set n to n + 1
                else
                    error "error: timed out"
                end if
            end repeat
        end tell
    end tell
end run

下の記事を参考にして、Automator でデータを取得、加工、送信し、その後は Google Apps Script でデコード、スプレッドシートに追記、、、とすればできるかもしれません。

ブラウザ上のテキストをGoogleスプレッドシートに追記でメモるAutomatorクイックアクション & Google Apps Script

https://ryjkmr.com/browse-text-memo-to-google-ss/

私は Google スプレッドシートを使ったことがないので分かりませんが...、ご参考まで。

ここから先は AppleScript でキーボードの操作をするのですが、本当にできるのかな？

以下は Google のトップページを開いて、「コマンド+V」「リターン」とする AppleScript です。これを応用して Google スプレッドシートの操作にトライしてみてください。(私は Google スプレッドシートのことを知らないのでコードは書けません...)

# Google のトップページを開く
tell application "Google Chrome"
    tell window 1
        open location "https://www.google.com/"
        set n to 0
        repeat while active tab is loading
            delay 1
            if n < 5 then
                set n to n + 1
            else
                error "timed out"
            end if
        end repeat
    end tell
end tell

set the clipboard to "apple" # apple をクリップボードにコピー

# コマンド+V、リターン
tell application "System Events"
    tell process "Google Chrome"
        set frontmost to true
        keystroke "v" using {command down} # command + v
        delay 0.5
        keystroke return # return
        delay 0.5
    end tell
end tell